import processing.opengl.*;


int num = 1000; 
Particule[] dots = new Particule[num]; 
Bloc temp;
Vector blocs;
int dim = 300;
float GRAV=0.1;
float FRICTION=0.999;
float CHOC=1.6;
color[] goodcolor = {#4b6576, #809ca4, #708b9c};// #79746e, #755d35, #937343, #9c6b4b, #ab8259, #aa8a61, #578375, #f0f6f2, #d0e0e5, #d7e5ec, #d3dfea, #c2d7e7, #a5c6e3, #a6cbe6, #adcbe5, #77839d, #d9d9b9, #a9a978, #727b5b, #6b7c4b, #546d3e, #47472e, #727b52, #898a6a, #919272, #AC623b, #cb6a33, #9d5c30, #843f2b, #652c2a, #7e372b, #403229, #47392b, #3d2626, #362c26, #57392c, #998a72, #864d36, #544732 };
  color somecolor() {
    // pick some random good color
    return goodcolor[int(random(goodcolor.length))];
  }

  void setup()
  {
    size(dim, dim,OPENGL);
    //frameRate(40);
    noStroke(); 
    smooth();
    background(255);
    for(int i=0; i<num; i++) { 
      dots[i] = new Particule();
    }  
    noStroke(); 
    smooth();
    background(255);
    blocs=new Vector();
  }

  void draw() 
  {
    fill(255,10);
    rect(0,0,dim,dim);
    for(int i=0; i<num; i++) { 
      dots[i].update(); 
      dots[i].draw(); 
    }  
    stroke(0);
    for(int i=0;i<blocs.size();i++){
       ((Bloc)blocs.get(i)).draw();
    }
  }


 // void  mousePressed(){
 //   setup(); 
 // }
  
  void mousePressed(){
    temp = new Bloc(mouseX,mouseY);
  }
  
  void mouseReleased(){
    temp.end(mouseX, mouseY);
    blocs.add(temp);
  }
  
  void keyPressed(){
     blocs=new Vector(); 
  }

class Bloc
{
  float startx,starty;
  float endx, endy;
  float normx,normy;
  Bloc(int x, int y){
     startx=x;
     starty=y; 
  }
  
  void end(int x,int y){
     endx=x;
     endy=y; 
     normy = -1*(endx-startx);
     normx = endy-starty;
     float norm = (float)Math.sqrt(normx*normx+normy*normy);
     normx/=norm;
     normy/=norm;
  }
  
  void draw(){
    color(100);
    line(startx,starty,endx,endy); 
  }
}
  class Particule
  { 
    // Screen values 
    float posx,posy,lastposx,lastposy;
    float speedx,speedy;
    color mic;

    // Constructor
    Particule() 
    { 
      posx = random(dim);
      posy = random(dim);
      lastposx=posx;
      lastposy=posy;
      speedx=random(10)-5;
      speedy=0;
      mic = somecolor();
    } 
    
    
    void rebirth(){
      speedx=random(1)-.5;
      speedy=0; 
      //posx=mouseX+random(20)-10;
      posx=random(dim);
      posy=-10;
      lastposx=posx;
      lastposy=posy;
    }

    void update() 
    { 
      speedy+=GRAV;
      speedy*=FRICTION;
      speedx*=FRICTION;
      lastposy=posy;
      lastposx=posx;
      posy+=speedy;
      posx+=speedx;
      if(posy>dim) rebirth();
      if(posx>dim) rebirth();
      if(posx<0) rebirth();
      
      for (int i=0;i<blocs.size();i++){
         Bloc temp = (Bloc)blocs.get(i);
         float denum = (temp.endy-temp.starty)*(posx-lastposx)-(temp.endx-temp.startx)*(posy-lastposy);
          if (denum!=0) {
            float ua = (temp.endx-temp.startx)*(lastposy-temp.starty)-(temp.endy-temp.starty)*(lastposx-temp.startx);
            ua = ua / denum;
            float ub = (posx-lastposx)*(lastposy-temp.starty)-(posy-lastposy)*(lastposx-temp.startx);
            ub = ub / denum;
            if ((ua>=0)&&(ua<=1)&&(ub>=0)&&(ub<=1)) {
               //intersection 
               float dot = temp.normx*(speedx) + temp.normy*(speedy);
               speedx -= CHOC*dot*temp.normx;
               speedy -= CHOC*dot*temp.normy;
               speedx+=random(2)-1;
               speedy+=random(2)-1;
               float x = lastposx + ua*0.8*(posx-lastposx);
               float y = lastposy + ua*0.8*(posy-lastposy);		
               posx=x;
               posy=y;
            }
         }  
      }
    } 



    void draw() 
    { 
      stroke(mic,100);
      line(lastposx, lastposy, posx, posy);
      //fill(mic);
      //ellipse(posx,posy,1,1);
    } 
  }